Функция PAD()

Возвращает самый последний заголовок меню, выбранный из строки меню, в виде строки прописных символов.

Синтаксис:

PAD()

Результат:
Символьный.

Комментарии:
Чтобы функция PAD( ) могла возвратить заголовок меню, строка меню должна быть определена и активна. Строки меню создаются и активизируются с помощью команд DEFINE MENU и ACTIVATE MENU.
Функцию PAD( ) можно также использовать по отношению к системной строке меню Visual FoxPro.
Функция PAD( ) возвращает пустую строку, если строка меню не определена или не активна или если PAD( ) выдана из окна команд.

Пример:

* В данном примере функция PAD( ) используется для передачи в
* процедуру заголовка меню.
* Текущая системная строка меню Visual FoxPro сохраняется в памяти по
* команде SET SYSMENU SAVE, и все заголовки системных меню убираются
* по команде SET SYSMENU TO.
* По команде DEFINE PAD создается несколько заголовков системных
* меню. При выборе заголовка меню функция PAD( ) передает этот
* заголовок в процедуру choice. Процедура choice отображает выбранный
* заголовок меню и имя строки меню. Если выбрать заголовок меню Exit,
* восстанавливается первоначальная система меню Visual FoxPro.
*** Name this program PADEXAM.PRG ***

CLEAR
SET SYSMENU SAVE
SET SYSMENU TO
DEFINE PAD padSys OF _MSYSMENU PROMPT '\<System' COLOR SCHEME 3 ;
	KEY ALT+S, ''
DEFINE PAD padEdit OF _MSYSMENU PROMPT '\<Edit' COLOR SCHEME 3 ;
	KEY ALT+E, ''
DEFINE PAD padRecord OF _MSYSMENU PROMPT '\<Record' COLOR SCHEME 3 ;
	KEY ALT+R, ''
DEFINE PAD padWindow OF _MSYSMENU PROMPT '\<Window' COLOR SCHEME 3 ;
	KEY ALT+W, ''
DEFINE PAD padReport OF _MSYSMENU PROMPT 'Re\<ports' COLOR SCHEME 3 ;
	KEY ALT+P, ''
DEFINE PAD padExit OF _MSYSMENU PROMPT 'E\<xit' COLOR SCHEME 3 ;
	KEY ALT+X, ''
ON SELECTION MENU _MSYSMENU ;
	DO choice IN padexam WITH PAD( ), MENU( )
PROCEDURE choice
PARAMETERS gcPad, gcMenu
WAIT WINDOW 'You chose ' + gcPad + ;
	' from menu ' + gcMenu NOWAIT
IF gcPad = 'PADEXIT'
	SET SYSMENU TO DEFAULT
ENDIF

Предыдущий Шаг | Следующий Шаг | Оглавление
Автор Каев Артем.