www.ПЕРВЫЕ ШАГИ.ru :: Свойства DynamicBackColor, DynamicForeColor

Задают цвет фона и основной цвет символов объекта Column. Причем цвета на этапе выполнения заново вычисляются при каждом обновлении элемента управления Grid.

Применение:
Column.

Синтаксис:

Column.DynamicBackColor[ = cExpression]
Column.DynamicForeColor[ = cExpression]

Установки:
cExpression
Задает выражение, заключаемое в кавычки, которое на этапе выполнения заново вычисляется при каждом обновлении элемента управления Grid. Результатом такого вычисления должно быть одиночное значение цвета.

Комментарии:
Доступно на этапе разработки и для чтения-записи на этапе выполнения.
Замечание. С помощью свойств DynamicBackColor и DynamicForeColor можно создавать специальные эффекты, например отображать нечетные строки зеленым цветом, а четные серым.

Пример:

* В следующем примере использовано свойство DynamicBackColor и метод
* SetAll, с помощью которых задаются цвета фона для записей в элементе
* управления Grid. Если запись, отображенная в сетке, имеет четный
* номер, значением ее свойства DynamicBackColor является белый цвет, в
* противном случае ѕ зеленый.
* Элемент управления Grid размещается в форме, затем открывается
* таблица customer, содержимое которой отображается в сетке. Свойство
* Caption используется для задания другого названия заголовка (Customer
* ID) поля CUST_ID. В форму включается командная кнопка, закрывающая
* ее.

CLOSE ALL  && Close tables and databases
OPEN DATABASE (HOME( ) + 'samples\data\testdata')

USE customer  IN 0  && Opens Customer table

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .f.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject('grdGrid1','Grid')  && Add Grid control

frmMyForm.grdGrid1.Left = 25    && Adjust Grid position

frmMyForm.grdGrid1.SetAll("DynamicBackColor", ;
	"IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255) ;
	, RGB(0,255,0))", "Column")  && Alternate white and green records

frmMyForm.grdGrid1.Visible = .T.  && Grid control visible
frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible
frmMyForm.grdGrid1.Column1.Header1.Caption = 'Customer ID'

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 210  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
		CLOSE ALL  && Close table and database
ENDDEFINE