www.ПЕРВЫЕ ШАГИ.ru :: Свойство Closable

Определяет, можно ли закрыть объект Form, дважды щелкнув кнопку управляющего меню или выбрав в этом меню команду Close.

Применение:
Form, _SCREEN

Синтаксис:

Object.Closable[ = lExpr]

Установки:
lExpr
Для свойства Closable предусмотрены следующие установки:

"Истина" (.T.) - (По умолчанию) Объект Form может быть закрыт, и в управляющее меню добавляется команда Close.
"Ложь" (.F.) - Объект Form нельзя закрыть с помощью управляющего меню, и в этом меню нет команды Close.

Комментарии:
Доступно на этапе разработки и на этапе выполнения.

Пример:

* В следующем примере показано, как использовать свойство Closable,
* чтобы предотвратить закрытие формы управляющим меню. Свойство
* Closable устанавливается как "ложь" (.F.), запрещая закрывать форму с
* помощью управляющего меню. Если это свойство установлено как
* "истина" (.T.) и форма закрывается управляющим меню, следует
* использовать CLEAR EVENTS для прекращения обработки событий и
* остановки программы.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
	Caption = 'Slant \<Up'  && Caption on the Command button
	Left = 50  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height
	
	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='/'  && Slant up
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
	Caption = 'Slant \<Down'  && Caption on the Command button
	Left = 200  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='\'  && Slant down
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 150  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE